[ASP.NET MVC] さくっと RSS フィードを出力する

Imports System.Net
Imports System.Web.Http

Namespace Controllers
    Public Class SpacoController
        Inherits ApiController
    End Class
End Namespace

<HttpGet>
Public Function GetALl(Optional offset As Integer = 0,
                       Optional count As Integer = 100) As HttpResponseMessage
    If offset < 0 Then
        offset = 0
    End If

    If count < 0 OrElse count > 100 Then
        count = 100
    End If

    Dim res = New HttpResponseMessage(HttpStatusCode.OK)
    res.Content = New StringContent(CreateFeed(offset, count), Encoding.UTF8, "application/xml")
    Return res
End Function

Public Class ComicItem
    Property Title As String
    Property Description As String
    Property PubDate As DateTime
    Property ModifiedDate As DateTime
    Property Link As String
    Property Id As String
    Property Volume As Integer
    Property IsAvailable As Boolean
    Property MediaUrl As String
    Property ThumbnailUrl As String
    Property Creator As String
    Property Guid As String
End Class

Private Function CreateFeed(offset As Integer, count As Integer) As String

    ' ダミーデータ作成
    Dim channelPubDate = Now
    Dim items = New List(Of ComicItem)

    For i = offset + 1 To count
        Dim item = New ComicItem With {
            .Title = "タイトル" & i.ToString,
            .PubDate = Now.AddDays(count - i),
            .ModifiedDate = Now.AddDays(count - i),
            .Link = "http://pronama.jp/?" & i.ToString,
            .Id = i.ToString,
            .Volume = i,
            .IsAvailable = True,
            .MediaUrl = "http://pronama.jp/?media" & i.ToString,
            .ThumbnailUrl = "http://pronama.jp/?thumbnail" & i.ToString,
            .Creator = "Creator",
            .Guid = "http://pronama.jp/?" & i.ToString}

        items.Add(item)
    Next

    ' XDocument 作成
    Dim xml =
    <?xml version="1.0" encoding="UTF-8"?>
    <rss version="2.0"
        xmlns:dc="http://purl.org/dc/elements/1.1/"
        xmlns:dcndl="http://ndl.go.jp/dcndl/terms/"
        xmlns:media="http://search.yahoo.com/mrss/"
        xmlns:p="http://pinga.mu/terms/"
        >
        <channel>
            <title>すぱこー</title>
            <link>https://pronama.jp/tag/spaco/</link>
            <description>高校生の暮井 慧（プロ生ちゃん）と、部活「情報処理研究会」のメンバー 戸増千由莉とフィネス・ヒルヴィレッジが活躍する Web 4コマ漫画「すぱこー」！</description>
            <pubDate><%= channelPubDate.ToString("r") %></pubDate>
            <image>https://pronama.jp/wp-content/uploads/2015/05/spaco_banner.png</image>
            <dc:creator>池村ヒロイチ/プログラミング生放送</dc:creator>
            <%= From i In items
                Select <item>
                            <title><%= i.Title %></title>
                            <dc:creator><%= i.Creator %></dc:creator>
                            <link><%= i.Link %></link>
                            <pubDate><%= i.PubDate.ToString("r") %></pubDate>
                            <description><%= i.Description %></description>
                            <dcndl:volume><%= i.Volume %></dcndl:volume>
                            <dc:modified><%= i.ModifiedDate.ToString("s") %></dc:modified>
                            <p:isAvailable><%= If(i.IsAvailable, "true", "false") %></p:isAvailable>
                            <media:content url=<%= i.MediaUrl %>></media:content>
                            <media:thumbnail url=<%= i.ThumbnailUrl %>></media:thumbnail>
                            <guid isPermaLink="false"><%= i.Guid %></guid>
                        </item>
            %>
        </channel>
    </rss>

    ' XML 文字列を返す
    Return xml.ToString
End Function

Imports <xmlns:dc="http://purl.org/dc/elements/1.1/">
Imports <xmlns:dcndl="http://ndl.go.jp/dcndl/terms/">
Imports <xmlns:media="http://search.yahoo.com/mrss/">
Imports <xmlns:p="http://pinga.mu/terms/">

<HttpGet>
<CacheOutput(ClientTimeSpan:=100, ServerTimeSpan:=100)>
Public Function GetALl(Optional offset As Integer = 0, Optional count As Integer = 100) As HttpResponseMessage
    ' ...
End Sub